Приведение уравнения линии второго порядка на плоскости к каноническому виду. Ориентированы на самостоятельное изучение пакета Maple пользователями

Приведение уравнения линии второго порядка на плоскости к каноническому виду

Для лучшего понимания данного материала приводятся некоторые сведения из курса аналитической геометрии.

Дано уравнение

в котором по крайней мере один из коэффициентов A, B, C не равен нулю. Этому уравнению может соответствовать некоторый геометрический образ на плоскости. Требуется с помощью поворота и параллельного переноса осей координат перейти к некоторой новой системе координат (x₂; y₂), чтобы в этой системе первоначальное уравнение после преобразований по возможности перешло в уравнение одной из кривых второго порядка: эллипса, гиперболы либо параболы (иногда упрощенное уравнение задает одну или две прямые, одну точку или даже пустое множество). Такой вид называется каноническим.

Если , то вначале потребуется провести поворот осей координат. Пусть оси координат Ox и Oy повернуты против часовой стрелки на некоторый острый угол a, тогда координаты любой точки (x; y) в первоначальной системе связаны с ее координатами (x₁; y₁) в новой системе следующими уравнениями:

Возьмем первые три слагаемых левой части первоначального уравнения, которые будут являться однородным многочленом от переменных. Обозначим этот многочлен

.

После подстановки формул преобразования координат в последнее уравнение оно при любом a оно примет вид

,

и требуется подобрать такой угол a, при котором , т.е.

.

Известно, что таким требованиям удовлетворяют корни уравнения

.

Это уравнение всегда имеет два действительных корня, причем по теореме Виета , откуда . Достаточно взять положительный корень уравнения, т.е. угол в первой координатной четверти (другим корнем будет угол, ему перпендикулярный и находящийся в четвертой координатной четверти). Косинус и синус этого угла можно получить по формулам

Зная эти величины, можно подставить их в формулы преобразования координат, после проведения которого первоначальное уравнение гарантированно примет вид

.

Параллельный перенос осей координат производится при выполнении по крайней мере одного из неравенств . Необходимо рассмотреть следующие случаи.

а) Если , то можно параллельно перенести оси координат и перейдя к новым координатам (x₂; y₂) так, чтобы уравнение приняло вид

.

Если при этом A₁ и C₁ имеют одинаковые знаки, то уравнение называется эллиптическим, в противном случае гиперболическим. Если при этом F₂=0, то канонический вид уравнения получен, иначе он получается делением всего последнего уравнения на |F₂|.

б) Если  или , то такое уравнение называется параболическим. Тогда с помощью параллельного переноса осей координат оно может быть приведено к виду  или . Далее по возможности остается выразить какую-нибудь переменную через другую – если такая возможность имеется, то уравнение определяет параболу, в противном случае – одну или две прямые.

Рассмотрим оба случая, поскольку алгоритмы решения задачи в этих случаях различаются.

а) Эллиптическое и гиперболическое уравнения

Пример решения задачи: дано уравнение

ВНИМАНИЕ! В качестве B, D и E задаются коэффициенты при xy, x и y соответственно, делённые на 2!

> restart:

> with(plots):

Эта команда необходима для подключения расширенных средств графики.

> unprotect(D);

Эта команда крайне необходима – напомним, что по умолчанию D является оператором дифференцирования.

> A:=2: B:=4: C:=-4: D:=6*sqrt(5): E:=-6*sqrt(5): F:=4:

> eq1:=A*x^2+2*B*x*y+C*y^2+2*D*x+2*E*y+F=0;

> eqv:=B*k^2+(A-C)*k-B=0;

> K:=solve(eqv,k);

> if K[1]>0 then k:=K[1] else k:=K[2] fi;

> alpha:=arctan(k);

> sa:=sin(alpha); ca:=cos(alpha);

Найденные значения синуса и косинуса угла подставляются в формулы преобразования координат, которые, в свою очередь, подставляются в исходное уравнение, и затем оно упрощается.

> zam1:=x=x1*ca-y1*sa; zam2:=y=x1*sa+y1*ca;

> eq2:=subs(zam1,zam2,eq1);

> eq2:=simplify(eq2);

ВНИМАНИЕ! В данном случае коэффициенты при квадратах обоих переменных оказались не равными нулю. В противном случае («б») дальнейшие действия, правомочные для данного примера, правомочными уже не будут, и уравнение окажется параболическим – см. этот случай ниже.

> le:=lhs(eq2);

> A1:=coeff(le,x1,2); C1:=coeff(le,y1,2); D1:=coeff(le,x1,1); E1:=coeff(le,y1,1);

Производится параллельный перенос осей координат.

> zam3:=x1=x2-D1/(2*A1); zam4:=y1=y2-E1/(2*C1);

> eq3:=simplify(subs(zam3,zam4,eq2));

> l:=lhs(eq3); c:=coeff(coeff(l,x2,0),y2,0);

Переменная c есть свободное слагаемое левой части последнего уравнения. Дальнейшие шаги выполняются при условии .

> eq4:=l-c=rhs(eq3)-c;

Значение c переносится из левой части уравнения в правую. При необходимости уравнение делится на модуль c.

> if c<>0 then eq4:=lhs(eq4)/abs(c)=rhs(eq4)/abs(c) fi;

Наконец, получен канонический вид уравнения. Из теории известно, что такое уравнение в данном случае определяет гиперболу. Убедимся в этом, построив график этой линии. Масштаб по обеим переменным (от -10 до 10) взят, в общем-то, «на глазок», и при необходимости его впоследствии можно изменить и затем перерисовать график.

> implicitplot(eq4,x2=-10..10,y2=-10..10,color=black);

б) Параболическое уравнение

Пример решения задачи: дано уравнение

ВНИМАНИЕ! В качестве B, D и E задаются коэффициенты при xy, x и y соответственно, делённые на 2!

> restart:

> with(plots):

Эта команда необходима для подключения расширенных средств графики.

> unprotect(D);

> A:=-1: B:=2: C:=-4: D:=6*sqrt(5): E:=-6*sqrt(5): F:=4:

> eq1:=A*x^2+2*B*x*y+C*y^2+2*D*x+2*E*y+F=0;

Признаком того, что уравнение является параболическим, является возможность представить первые 3 слагаемые его левой части в виде полного квадрата, умноженного на некоторое число. Начальные действия аналогичны действиям в предыдущем случае.

> eqv:=B*k^2+(A-C)*k-B=0;

> K:=solve(eqv,k);

> if K[1]>0 then k:=K[1] else k:=K[2] fi;

> alpha:=arctan(k);

> sa:=sin(alpha); ca:=cos(alpha);

> zam1:=x=x1*ca-y1*sa; zam2:=y=x1*sa+y1*ca;

> eq2:=subs(zam1,zam2,eq1);

> eq2:=simplify(eq2);

Итак, слагаемое, содержащее , отсутствует, и уравнение является параболическим. Если бы отсутствовало слагаемое, содержащее , то дальнейшие действия были бы аналогичными, только переменные поменялись бы местами.

> le2:=lhs(eq2): A1:=coeff(le2,x1,2); C1:=coeff(le2,y1,2);

В данном случае вначале параллельно переносится ось y₁, затем параллельно переносится ось x₁. Если бы C1 было бы равно нулю, то параллельный перенос осей осуществлялся бы наоборот. Поэтому все нижеследующие команды необходимо ввести в одной исполняемой группе, а завершать ввод всех строк, кроме последней, необходимо комбинацией клавиш Shift+Enter (как в Word).

> if A1=0 then
  E1:=coeff(le2,y1,1); zam4:=y1=y2-E1/(2*C1);
  eq3:=simplify(subs(zam4,eq2));
  le3:=lhs(eq3); D2:=coeff(le3,x1,1);
  F2:=coeff(coeff(le3,x1,0),y2,0);
  zam3:=x1=x2-F2/D2; eq4:=subs(zam3,eq3);
  eq5:=x2=solve(eq4,x2);
else
  D1:=coeff(le2,x1,1); zam3:=x1=x2-D1/(2*A1);
  eq3:=simplify(subs(zam3,eq2));
  le3:=lhs(eq3); E2:=coeff(le3,y1,1);
  F2:=coeff(coeff(le3,x2,0),y1,0);
  zam4:=y1=y2-F2/E2; eq4:=subs(zam4,eq3);
  eq5:=y2=solve(eq4,y2);
fi;

Наконец, получен канонический вид уравнения. Из теории известно, что такое уравнение определяет параболу. Убедимся в этом, построив график этой линии. Масштаб по обеим переменным (от -10 до 10) взят, в общем-то, «на глазок», и при необходимости его впоследствии можно изменить и затем перерисовать график.

> implicitplot(eq5,x2=-10..10,y2=-10..10,color=black);